Platinum Skills NPC Missing 3rd Job References

Originally posted by [b]jTynne[/b]
I can't see my own attachment, so pasting the code below.:

[code]//===== rAthena Script =======================================
//= Platinum Skills
//===== By: ==================================================
//= Keichii, DarkChild
//===== Current Version: =====================================
//= 2.7
//===== Compatible With: =====================================
//= rAthena SVN
//===== Description: =========================================
//= Single NPC that assigns quests skills for all classes
//===== Additional Comments: =================================
//= 2.0 Added advanced classes by ShadowLady.
//= 2.1 Added baby clases by Midas
//= 2.2 Simplified Job Checks [Silentdragon]
//= 2.3 Thehell? Cleaned up script removed the nastiness. Also added rebirth skills. [Spre]
//= 2.4 Added Advanced skills. [Spre]
//= 2.5 Added dialog for if the user is none of the listed jobs. [Kisuka]
//= 2.6 Fixed 2nd advanced classes not being able to get their advanced skills. [Ancyker]
//= 2.7 Rewrote to give all correct skills to all proper classes. [Paradox924X]
//= 2.8 Updated to honor third job classes. [jTynne]
//============================================================

prt_in,45,112,4 script Platinum Skill NPC 94,{
mes "[Platinum Skill NPC]";
mes "I can give you the special skills available to your job.";
mes "Would you like these skills now?";
next;
if (select("Yes Please:No") == 2) {
mes "[Platinum Skill NPC]";
mes "Have a nice day... >.>";
close;
}
skill 142,1,0; // First Aid
if (BaseClass == Job_Novice) {
skill 143,1,0; // Play Dead
} else if (BaseClass == Job_Swordman) {
skill 144,1,0; // Moving HP-Recovery
skill 145,1,0; // Fatal Blow
skill 146,1,0; // Auto Berserk
} else if (BaseClass == Job_Mage) {
skill 157,1,0; // Energy Coat
} else if (BaseClass == Job_Archer) {
skill 147,1,0; // Arrow Crafting
skill 148,1,0; // Arrow Repel
} else if (BaseClass == Job_Merchant) {
skill 153,1,0; // Cart Revolution
skill 154,1,0; // Change Cart
skill 155,1,0; // Crazy Uproar
} else if (BaseClass == Job_Thief) {
skill 149,1,0; // Sand Attack
skill 150,1,0; // Back Slide
skill 151,1,0; // Find Stone
skill 152,1,0; // Stone Fling
} else if (BaseClass == Job_Acolyte) {
skill 156,1,0; // Holy Light
}
if (Class == Job_Knight || Class == Job_Lord_Knight || Class == Job_Rune_Knight || Class == Job_Rune_Knight_T) {
skill 1001,1,0; // Charge Attack
} else if (Class == Job_Crusader || Class == Job_Paladin || Class == Job_Royal_Guard || Class == Job_Royal_Guard_T) {
skill 1002,1,0; // Shrink
} else if (Class == Job_Wizard || Class == Job_High_Wizard || Class == Job_Warlock || Class == Job_Warlock_T) {
skill 1006,1,0; // Sight Blaster
} else if (Class == Job_Sage || Class == Job_Professor || Class == Job_Sorcerer || Class == Job_Sorcerer_T) {
skill 1007,1,0; // Create Elemental Converter
skill 1008,1,0; // Elemental Change Water
skill 1017,1,0; // Elemental Change Earth
skill 1018,1,0; // Elemental Change Fire
skill 1019,1,0; // Elemental Change Wind
} else if (Class == Job_Hunter || Class == Job_Sniper || Class == Job_Ranger || Class == Job_Ranger_T) {
skill 1009,1,0; // Phantasmic Arrow
} else if (Class == Job_Bard || Class == Job_Clown || Class == Job_Minstrel || Class == Job_Minstrel_T) {
skill 1010,1,0; // Pang Voice
} else if (Class == Job_Dancer || Class == Job_Gypsy || Class == Job_Wanderer || Class == Job_Wanderer_T) {
skill 1011,1,0; // Wink of Charm
} else if (Class == Job_Blacksmith || Class == Job_Whitesmith || Class == Job_Mechanic || Class == Job_Mechanic_T) {
skill 1012,1,0; // Unfair Trick
skill 1013,1,0; // Greed
} else if (Class == Job_Alchemist || Class == Job_Creator || Class == Job_Genetic || Class == Job_Genetic_T) {
skill 238,1,0; // Bioethics
} else if (Class == Job_Assassin || Class == Job_Assassin_Cross || Class == Job_Guillotine_Cross || Class == Job_Guillotine_Cross_T) {
skill 1003,1,0; // Sonic Acceleration
skill 1004,1,0; // Throw Venom Knife
} else if (Class == Job_Rogue || Class == Job_Stalker || Class == Job_Shadow_Chaser || Class == Job_Shadow_Chaser_T) {
skill 1005,1,0; // Close Confine
} else if (Class == Job_Priest || Class == Job_High_Priest || Class == Job_Arch_Bishop || Class == Job_Arch_Bishop_T) {
skill 1014,1,0; // Redemptio
} else if (Class == Job_Monk || Class == Job_Champion || Class == Job_Sura || Class == Job_Sura_T) {
skill 1015,1,0; // Ki Translation
skill 1016,1,0; // Ki Explosion
}
mes "[Platinum Skill NPC]";
mes "There you go!";
close;
}[/code]

Originally posted by [b]EvilPuncker[/b]
missing babies? ^^

Originally posted by [b]Euphy[/b]
Fixed in [rev=16216].

Originally posted by [b]EvilPuncker[/b]
so sad that you took out all skill names